(require '[fixpoint.core :as fix]
         '[fixpoint.datasource.postgresql :as pg])

(def test-db
  (pg/make-datasource
    :test-db
    {:connection-uri "jdbc:postgresql://..."}))

(defn- person
  [reference name age]
  (-> {:db/table :people
       :name     name
       :age      age
       :active   true}
      (fix/as reference)
      (fix/on-datasource :test-db)))
(defn- post
  [reference person-reference text]
  (-> {:db/table  :posts
       :text      text
       :author-id person-reference}
      (fix/as reference)
      (fix/on-datasource :test-db)))

(def +fixtures+
  [(person :person/me  "me" 27)
   (person :person/you "you" 29)
   (post   :post/happy :person/me  "Awesome.")
   (post   :post/meh   :person/you "Meh.")])

(post :post/question [:post/happy :author-id] "Do you really think so?")

(fix/with-rollback-datasource [_ test-db]
  (fix/with-data +fixtures+
    (vector
      (fix/property :person/me)
      (fix/property :person/you :created-at)
      (fix/property :post/happy :author-id)
      (fix/id :post/meh))))
;; => [{:id 3,
;;      :name "me",
;;      :age 27,
;;      :active true,
;;      :created-at #inst "2017-03-10T11:13:06.452505000-00:00"},
;;     #inst "2017-03-10T11:13:06.452505000-00:00"
;;     3
;;     4]

(require '[clojure.test :refer :all]
         '[clojure.java.jdbc :as jdbc])
(use-fixtures
  :once
  (fix/use-datasources db)
  (fix/use-data +fixtures+))
(deftest t-people-query
  (let [db (fix/raw-datasource :test-db)]
    (is (= #{"me" "you" "someone"}
           (->> (jdbc/query db ["select name from people"])
                (map :name)
                (set))))))

(run-tests)
;; FAIL in (t-people-query) (b88f62883cbaa1a3f26472a814829fe3c5933107-init.clj:3)
;; expected: (= #{"someone" "you" "me"} (->> (db/query db ["select name from people"]) (map :name) (set)))
;;  actual: (not (= #{"someone" "you" "me"} #{"you" "me"}))
;;
;; Ran 1 tests containing 1 assertions.
;; 1 failures, 0 errors.
;; => {:test 1, :pass 0, :fail 1, :error 0, :type :summary}