' ---------------------------------------------------------------
' From the book "Windows Server Cookbook" by Robbie Allen
' ISBN: 0-596-00633-0
' ---------------------------------------------------------------
Option Explicit
On Error Resume Next
Dim strServerList : strServerList = "c:\servers.txt"
Dim strServerPass : strServerPass = "c:\pass.txt"
Dim strServerFail : strServerFail = "c:\fail.txt"
Dim strAdminAccount : strAdminAccount = "administrator"
Dim strNewPassword : strNewPassword   = "My!New!Password"
Dim objFSO, objServersFile, objPassFile, objFailFile
Set objFSO  = CreateObject("Scripting.FileSystemObject")
Set objServersFile = objFSO.OpenTextFile(strServerList)
Set objPassFile    = objFSO.CreateTextFile(strServerPass)
Set objFailFile    = objFSO.CreateTextFile(strServerFail)
Do While not objServersFile.AtEndOfStream
     Dim strServer : strServer = objServersFile.ReadLine
     Dim objAdmin
     Set objAdmin = GetObject("WinNT://" & strServer & "/" _
                    & strAdminAccount & ",user")
     if Err then
        objFailFile.WriteLine strServer & " failed: " & Err.Description
        Err.Clear
     else
        objAdmin.SetPassword strNewPassword
        objAdmin.SetInfo
        if Err then
           objFailFile.WriteLine strServer & " failed: " & Err.Description
           Err.Clear
        else
           objPassFile.WriteLine strServer & " successful"
        end if
     end if
Loop
WScript.Echo "Complete."
' Close open files
objServersFile.close
objFailFile.close
objPassFile.close