' From the book "Active Directory, Third Edition" 
' ISBN: 0-596-10173-2
strComputer = "."
intMaxFileSize = 10 * 1024 * 1024   ' << 10MB
intOverwriteOutDated = 180          ' << 6 months
   
Set objWMI = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set objELF = objWMI.InstancesOf("Win32_NTEventLogFile")
' Iterate over each Event Log
For Each objEL In objELF
   WScript.Echo objEL.LogFileName & " Log:"
   WScript.Echo " FileSize: " & objEL.FileSize
   
   ' If the size has not been set yet, set it
   If objEL.MaxFileSize <> intMaxFileSize Then
      WScript.Echo " ** Setting MaxFileSize: " & intMaxFileSize & " (new) " & _
                   objEL.MaxFileSize & " (current)"
      objEL.MaxFileSize = intMaxFileSize
      objEL.Put_
   Else 
      WScript.Echo " MaxFileSize: " & objEL.MaxFileSize
   End If
   
   WScript.Echo " Name: " & objEL.Name
   WScript.Echo " NumberOfRecords: " & objEL.NumberOfRecords
   
   ' If the overwrite date has not been set, set it
   WScript.Echo " OverwritePolicy: " & objEL.OverwritePolicy
   If objEL.OverwriteOutDated <> intOverwriteOutDated Then
      WScript.Echo " ** Setting OverwriteOutDated: " & _
                   intOverwriteOutDated & " (new) " & _ 
                   objEL.OverwriteOutDated & " (current)"
      objEL.OverwriteOutDated = intOverwriteOutdated
      objEL.Put_
   Else 
      WScript.Echo " OverwriteOutDated: " & objEL.OverwriteOutDated
   End If
   
   WScript.Echo ""
Next
WScript.Echo "The script has completed successfully."