| CARVIEW |
Select Language
HTTP/2 200
server: nginx
content-type: text/plain;charset=UTF-8
content-encoding: gzip
content-security-policy: default-src 'self'; connect-src 'self' *.google-analytics.com; img-src 'self' data: www.google-analytics.com www.googletagmanager.com; script-src 'self' 'unsafe-inline' www.google-analytics.com www.googletagmanager.com; style-src 'self'; report-uri /csp-reports
accept-ranges: bytes
age: 0
date: Wed, 15 Oct 2025 15:39:37 GMT
via: 1.1 varnish
x-served-by: cache-bom-vanm7210073-BOM
x-cache: MISS
x-cache-hits: 0
x-timer: S1760542776.241317,VS0,VE777
vary: Accept-Encoding
strict-transport-security: max-age=31557600
content-length: 1509
package TAP::Parser::SourceHandler::Executable;
use strict;
use warnings;
use File::Spec;
use TAP::Parser::IteratorFactory ();
use TAP::Parser::Iterator::Process ();
use base 'TAP::Parser::SourceHandler';
TAP::Parser::IteratorFactory->register_handler(__PACKAGE__);
=head1 NAME
TAP::Parser::SourceHandler::Executable - Stream output from an executable TAP source
=head1 VERSION
Version 3.50
=cut
our $VERSION = '3.50';
=head1 SYNOPSIS
use TAP::Parser::Source;
use TAP::Parser::SourceHandler::Executable;
my $source = TAP::Parser::Source->new->raw(['/usr/bin/ruby', 'mytest.rb']);
$source->assemble_meta;
my $class = 'TAP::Parser::SourceHandler::Executable';
my $vote = $class->can_handle( $source );
my $iter = $class->make_iterator( $source );
=head1 DESCRIPTION
This is an I L - it has 2 jobs:
1. Figure out if the L it's given is an executable
command (L).
2. Creates an iterator for executable commands (L).
Unless you're writing a plugin or subclassing L, you
probably won't need to use this module directly.
=head1 METHODS
=head2 Class Methods
=head3 C
my $vote = $class->can_handle( $source );
Only votes if $source looks like an executable file. Casts the
following votes:
0.9 if it's a hash with an 'exec' key
0.8 if it's a .bat file
0.75 if it's got an execute bit set
=cut
sub can_handle {
my ( $class, $src ) = @_;
my $meta = $src->meta;
if ( $meta->{is_file} ) {
my $file = $meta->{file};
return 0.85 if $file->{execute} && $file->{binary};
return 0.8 if $file->{lc_ext} eq '.bat';
return 0.25 if $file->{execute};
}
elsif ( $meta->{is_hash} ) {
return 0.9 if $src->raw->{exec};
}
return 0;
}
=head3 C
my $iterator = $class->make_iterator( $source );
Returns a new L for the source.
C<$source-Eraw> must be in one of the following forms:
{ exec => [ @exec ] }
[ @exec ]
$file
Cs on error.
=cut
sub make_iterator {
my ( $class, $source ) = @_;
my $meta = $source->meta;
my @command;
if ( $meta->{is_hash} ) {
@command = @{ $source->raw->{exec} || [] };
}
elsif ( $meta->{is_scalar} ) {
@command = File::Spec->rel2abs( ${ $source->raw } )
if ${ $source->raw };
}
elsif ( $meta->{is_array} ) {
@command = @{ $source->raw };
}
$class->_croak('No command found in $source->raw!') unless @command;
$class->_autoflush( \*STDOUT );
$class->_autoflush( \*STDERR );
push @command, @{ $source->test_args || [] };
return $class->iterator_class->new(
{ command => \@command,
merge => $source->merge
}
);
}
=head3 C
The class of iterator to use, override if you're sub-classing. Defaults
to L.
=cut
use constant iterator_class => 'TAP::Parser::Iterator::Process';
# Turns on autoflush for the handle passed
sub _autoflush {
my ( $class, $flushed ) = @_;
my $old_fh = select $flushed;
$| = 1;
select $old_fh;
}
1;
=head1 SUBCLASSING
Please see L for a subclassing overview.
=head2 Example
package MyRubySourceHandler;
use strict;
use Carp qw( croak );
use TAP::Parser::SourceHandler::Executable;
use base 'TAP::Parser::SourceHandler::Executable';
# expect $handler->(['mytest.rb', 'cmdline', 'args']);
sub make_iterator {
my ($self, $source) = @_;
my @test_args = @{ $source->test_args };
my $rb_file = $test_args[0];
croak("error: Ruby file '$rb_file' not found!") unless (-f $rb_file);
return $self->SUPER::raw_source(['/usr/bin/ruby', @test_args]);
}
=head1 SEE ALSO
L,
L,
L,
L,
L,
L,
L,
L
=cut