HTTP/2 200 date: Sat, 11 Oct 2025 18:25:19 GMT content-type: text/html server: cloudflare last-modified: Thu, 28 Oct 2010 14:02:44 GMT cf-cache-status: DYNAMIC vary: Accept-Encoding nel: {"report_to":"cf-nel","success_fraction":0.0,"max_age":604800} report-to: {"group":"cf-nel","max_age":604800,"endpoints":[{"url":"https://a.nel.cloudflare.com/report/v4?s=R49zX4MVonAZKhqxarWFT6mK%2BK%2BZF6D73gtrM%2BtBLOL6VA80A3UDiDziOZMuHU4MKZa0WOxTbhHToz7teXkCIFBXRDSLDuhHwKyucE8%3D"}]} content-encoding: gzip cf-ray: 98d066412bff47ce-BOM alt-svc: h3=":443"; ma=86400

Processing.js

Inheritance

A class can be defined using another class as a foundation. In object-oriented programming terminology, one class can inherit fi elds and methods from another. An object that inherits from another is called a subclass, and the object it inherits from is called a superclass. A subclass extends the superclass.

Original Processing.org Example: Inheritance

// All Examples Written by Casey Reas and Ben Fry
// unless otherwise stated.
SpinSpots spots;
SpinArm arm;
void setup() 
{
  size(200, 200);
  smooth();
  arm = new SpinArm(width/2, height/2, 0.01);
  spots = new SpinSpots(width/2, height/2, -0.02, 33.0);
}
void draw() 
{
  background(204);
  arm.update();
  arm.display();
  spots.update();
  spots.display();
}
class Spin 
{
  float x, y, speed;
  float angle = 0.0;
  Spin(float xpos, float ypos, float s) {
    x = xpos;
    y = ypos;
    speed = s;
  }
  void update() {
    angle += speed;
  }
}
class SpinArm extends Spin 
{
  SpinArm(float x, float y, float s) {
    super(x, y, s);
  }
  void display() {
    strokeWeight(1);
    stroke(0);
    pushMatrix();
    translate(x, y);
    angle += speed;
    rotate(angle);
    line(0, 0, 66, 0);
    popMatrix();
  }
}
class SpinSpots extends Spin 
{
  float dim;
  SpinSpots(float x, float y, float s, float d) {
    super(x, y, s);
    dim = d;
  }
  void display() {
    noStroke();
    pushMatrix();
    translate(x, y);
    angle += speed;
    rotate(angle);
    ellipse(-dim/2, 0, dim, dim);
    ellipse(dim/2, 0, dim, dim);
    popMatrix();
  }
}