package features.step_definitions
	{	
		import mypackage.components.MyComponent;
		import flash.events.Event;
	
		import org.flexunit.asserts.fail;
		import org.flexunit.async.Async;
		import org.fluint.uiImpersonation.UIImpersonator;
		import org.hamcrest.assertThat;
		import org.hamcrest.object.isTrue;
		import org.hamcrest.object.notNullValue;
	
		public class UI_Test_Environment_Steps
		{
			private var _myComponent:MyComponent;
		
			public function UI_Test_Environment_Steps()
			{
				super();
			}
		
			[Given (/^I have a visible asset$/ )]
			public function createVisibleAsset():void
			{
				_myComponent = new MyComponent()
			}
		
			[When ( /^I add it to the UI test environment$/, "async")]
			public function addToDisplayList():void
			{
				Async.proceedOnEvent( this, _myComponent, Event.ADDED_TO_STAGE );
				UIImpersonator.addChild( _myComponent );
			}
		
			[Then ( /^it can be seen$/ )]
			public function verifyComponent():void
			{
				assertThat( _myComponent.stage, notNullValue() );
				assertThat( _myComponent.visible, isTrue() );
			}
		
			public function destroy():void
			{
				UIImpersonator.removeChild( _myComponent );
				_myComponent = null;
			}
		}
	}